feat: Introduce Flake for development and builds

This PR introduces a Nix flake, allowing for InfiniTime to be built as a
Flake, including a FHS development environment.

It's derived from #1850 and
c57c57f3c6.

We also introduce `flake-compat`, allowing for non-Flake Nix mahcines to
use the project as-is, both for building (`default.nix`), and
development (`shell.nix`).

Additionally, we introduce `.envrc`, meaning that with `direnv`, the Nix
Flake is activated automatically.

Fixes #1850.

Signed-off-by: Dom Rodriguez <shymega@shymega.org.uk>

.envrc

@@ -0,0 +1 @@
+use flake

default.nix

@@ -0,0 +1,10 @@
+(import
+  (
+    let lock = builtins.fromJSON (builtins.readFile ./flake.lock); in
+    fetchTarball {
+      url = lock.nodes.flake-compat.locked.url or "https://github.com/edolstra/flake-compat/archive/${lock.nodes.flake-compat.locked.rev}.tar.gz";
+      sha256 = lock.nodes.flake-compat.locked.narHash;
+    }
+  )
+  { src = ./.; }
+).defaultNix

flake.lock

@@ -0,0 +1,42 @@
+{
+  "nodes": {
+    "flake-compat": {
+      "locked": {
+        "lastModified": 1696426674,
+        "narHash": "sha256-kvjfFW7WAETZlt09AgDn1MrtKzP7t90Vf7vypd3OL1U=",
+        "rev": "0f9255e01c2351cc7d116c072cb317785dd33b33",
+        "revCount": 57,
+        "type": "tarball",
+        "url": "https://api.flakehub.com/f/pinned/edolstra/flake-compat/1.0.1/018afb31-abd1-7bff-a5e4-cff7e18efb7a/source.tar.gz"
+      },
+      "original": {
+        "type": "tarball",
+        "url": "https://flakehub.com/f/edolstra/flake-compat/1.tar.gz"
+      }
+    },
+    "nixpkgs": {
+      "locked": {
+        "lastModified": 1725634671,
+        "narHash": "sha256-v3rIhsJBOMLR8e/RNWxr828tB+WywYIoajrZKFM+0Gg=",
+        "owner": "nixos",
+        "repo": "nixpkgs",
+        "rev": "574d1eac1c200690e27b8eb4e24887f8df7ac27c",
+        "type": "github"
+      },
+      "original": {
+        "owner": "nixos",
+        "ref": "nixos-unstable",
+        "repo": "nixpkgs",
+        "type": "github"
+      }
+    },
+    "root": {
+      "inputs": {
+        "flake-compat": "flake-compat",
+        "nixpkgs": "nixpkgs"
+      }
+    }
+  },
+  "root": "root",
+  "version": 7
+}

flake.nix

@@ -0,0 +1,113 @@
+{
+  description = "A very basic flake";
+
+  inputs = {
+    nixpkgs.url = "github:nixos/nixpkgs?ref=nixos-unstable";
+    flake-compat.url = "https://flakehub.com/f/edolstra/flake-compat/1.tar.gz";
+  };
+
+  outputs = { self, ... }@inputs:
+    let
+      forAllSystems = function:
+        inputs.nixpkgs.lib.genAttrs [
+          "x86_64-linux"
+          "aarch64-linux"
+        ]
+          (system: function (import inputs.nixpkgs {
+            inherit system;
+            config.allowUnfree = true;
+          }));
+    in
+    {
+      packages = forAllSystems (pkgs:
+        let
+          infinitime-nrf5-sdk = pkgs.nrf5-sdk.overrideAttrs (old: {
+            version = "15.3.0";
+            src = pkgs.fetchzip {
+              url = "https://nsscprodmedia.blob.core.windows.net/prod/software-and-other-downloads/sdks/nrf5/binaries/nrf5sdk153059ac345.zip";
+              sha256 = "sha256-pfmhbpgVv5x2ju489XcivguwpnofHbgVA7bFUJRTj08=";
+            };
+          });
+        in
+        with pkgs; {
+          default = stdenv.mkDerivation rec {
+            name = "infinitime";
+
+            src = fetchFromGitHub {
+              owner = "InfiniTimeOrg";
+              repo = "InfiniTime";
+              rev = "1.14.1";
+              hash = "sha256-IrsN+9LgEjgfoRR6H7FhsdLMK+GLxc41IBnSbdpwv/E=";
+              fetchSubmodules = true;
+            };
+
+            nativeBuildInputs = [
+              cmake
+              nodePackages.lv_font_conv
+              python3
+              python3.pkgs.cbor
+              python3.pkgs.click
+              python3.pkgs.cryptography
+              python3.pkgs.intelhex
+              python3.pkgs.pillow
+              adafruit-nrfutil
+              patch
+              git
+            ];
+
+            postPatch = ''
+              # /usr/bin/env is not available in the build sandbox
+              substituteInPlace src/displayapp/fonts/generate.py --replace "'/usr/bin/env', 'patch'" "'patch'"
+              substituteInPlace tools/mcuboot/imgtool.py --replace "/usr/bin/env python3" "${python3}/bin/python3"
+            '';
+
+            cmakeFlags = [
+              ''-DARM_NONE_EABI_TOOLCHAIN_PATH=${gcc-arm-embedded-10}''
+              ''-DNRF5_SDK_PATH=${infinitime-nrf5-sdk}/share/nRF5_SDK''
+              ''-DBUILD_DFU=1''
+              ''-DBUILD_RESOURCES=1''
+              ''-DCMAKE_SOURCE_DIR=${src}''
+            ];
+
+            installPhase = ''
+              SOURCES_DIR=${src} BUILD_DIR=. OUTPUT_DIR=$out ./post_build.sh
+            '';
+          };
+        });
+
+      devShells = forAllSystems (pkgs:
+        let
+          infinitime-nrf5-sdk = pkgs.nrf5-sdk.overrideAttrs (old: {
+            version = "15.3.0";
+            src = pkgs.fetchzip {
+              url = "https://nsscprodmedia.blob.core.windows.net/prod/software-and-other-downloads/sdks/nrf5/binaries/nrf5sdk153059ac345.zip";
+              sha256 = "sha256-pfmhbpgVv5x2ju489XcivguwpnofHbgVA7bFUJRTj08=";
+            };
+          });
+        in
+        {
+          default =
+            pkgs.buildFHSUserEnv {
+              name = "infinitime-devenv";
+              # build tools
+              targetPkgs = pkgs: (with pkgs; [
+                cmake
+                nodePackages.lv_font_conv
+                python3
+                python3.pkgs.cbor
+                python3.pkgs.click
+                python3.pkgs.cryptography
+                python3.pkgs.intelhex
+                adafruit-nrfutil
+
+                (pkgs.writeShellScriptBin "cmake_infinitime" ''
+                  cmake -DARM_NONE_EABI_TOOLCHAIN_PATH="${pkgs.gcc-arm-embedded-10}" \
+                        -DNRF5_SDK_PATH="${infinitime-nrf5-sdk}/share/nRF5_SDK" \
+                        "$@"
+                '')
+              ]);
+            };
+        });
+    };
+}
+      

shell.nix

@@ -0,0 +1,10 @@
+(import
+  (
+    let lock = builtins.fromJSON (builtins.readFile ./flake.lock); in
+    fetchTarball {
+      url = lock.nodes.flake-compat.locked.url or "https://github.com/edolstra/flake-compat/archive/${lock.nodes.flake-compat.locked.rev}.tar.gz";
+      sha256 = lock.nodes.flake-compat.locked.narHash;
+    }
+  )
+  { src = ./.; }
+).shellNix